Validar formato de documentos con Excel y similares

Recientemente se mostró una manera de verificar que todos los caracteres de un texto sean válidos, siguiendo con la misma teoría se realizaron unas adaptaciones de manera de obtener una formula que valide formatos, por ejemplo de documentos.

Cálculo en Microsoft Excel en español:

=SI(LARGO(A1) = LARGO(C1); SUMAPRODUCTO(((EXTRAE(C1; FILA(INDIRECTO("1:" & LARGO(C1))); 1) = "9") * (EXTRAE(A1; FILA(INDIRECTO("1:" & LARGO(A1))); 1) >= "0")*(EXTRAE(A1; FILA(INDIRECTO("1:" & LARGO(A1))); 1) <= "9") *1) + ((EXTRAE(MAYUSC(C1); FILA(INDIRECTO("1:" & LARGO(C1))); 1) = "A") * (EXTRAE(MAYUSC(A1); FILA(INDIRECTO("1:" & LARGO(A1))); 1) >= "A") * (EXTRAE(MAYUSC(A1); FILA(INDIRECTO("1:" & LARGO(A1))); 1) <= "Z") * 1) + ((EXTRAE(C1; FILA(INDIRECTO("1:" & LARGO(C1))); 1) = EXTRAE(A1;FILA(INDIRECTO("1:" & LARGO(A1))); 1)) * (EXTRAE(C1; FILA(INDIRECTO("1:" & LARGO(C1))); 1) <> "9") * (EXTRAE(MAYUSC(C1); FILA(INDIRECTO("1:" & LARGO(C1))); 1) <> "A") * 1)) = LARGO(C1))

En este montón de formulas, se valida que el número que se encuentra en la celda A1 se corresponda con el formato que esté definido en la celda C1.

Suponiendo que un documento válido es: 123-121289-00001-H. Se deberá definir el formato de la siguiente manera: 999-999999-99999-A

Donde:
"9" corresponde a dígitos numéricos (0 a 9)
"A" corresponde a letras, sin contemplar tildes, (de A a Z).
Y cualquier otro carácter (incluyendo resto de letras y se corresponde al mismo carácter.

Esta función podrá ser utilizada para validar datos de documentos como ser cédulas de identidad, pasaportes, DNI, DNA, NIF, NIT, RUC, RUT, tarjetas de crédito, y cualquier otro documento que presente un formato.

Hay que tener en cuenta que un documento que pase la validación del formato no quiere decir que sea correcto, ya que la numeración puede no estarlo. La numeración se valida con formulas específicas para cada documento.